Display bug with console/PNG feature

[misty]

(2019-05-22 19:55)NiKiZe Wrote:  So no gui on the wimboot lne, could you try with gui on the wimboot line?
I would expect you to get the same result there as well - just looking for a reproducable test case.

Great hearing that console clears it, maybe this is something that should be handled by iPXE boot part, or wimboot

@NiKiZe
My previous post only contained a part of my iPXE menu. The full menu that can hopefully be used to reproduce the display bug is contained below.

I should also mention for those that do not want to trawl through the lengthy thread on reboot.pro that this display bug was encountered with a Client system booting in UEFI mode with CSM disabled.

Stage 1 (menu item iscsia) booted fine and the display bug was not encountered. Stage 1 (SANHOOK the iSCSI Target and boot WinPE) was used to install Windows - using Windows setup.exe. After setup completed an automatic reboot occured.

The bug occurred when booting Stage 2 (menu item iscsib), executed after the Stage 1 reboot. Interestingly during one of my tests (after adding a displaybootmenu yes entry to the BCD store) a boot menu was correctly displayed followed by a Windows background image for a few seconds, then the console bug was encountered and I was not able to read the display.

Hope this makes sense.

Misty

Code:

#!ipxe
#SET BACKGROUND PICTURE AND PROCEED - IF ERROR, GOTO NEXT LINE
console --picture ipxe.png ||
iseq ${next-server} ${dhcp-server} && goto dhcp ||
set boot-url http://${next-server}
set boot-ip ${next-server}
goto main

:dhcp
set boot-url http://${dhcp-server}
set boot-ip ${dhcp-server}
goto main

#================ Main Menu =================
:main
menu iPXE boot menu
item --gap --           next-server - ${next-server}
item --gap --           dhcp-server - ${dhcp-server}
item --gap --           boot-url    - ${boot-url}
item --gap --           boot-ip     - ${boot-ip}
item --gap --         ----------------- Options --------------
item iscsia        iSCSI - Define IQN and SANHOOK (+wimboot)
item iscsib        iSCSI - Define IQN and SANBOOT
item winpe        WinPE (wimboot)
item --gap --         ------------------- Misc ---------------
item config        View configuration settings
item shell        Shell
item exit        Exit
choose target && goto ${target}

#============= END Main Menu ================

:iscsia
set gateway 0.0.0.0
set keep-san 1
set initiator-iqn iqn.client
echo -n Enter IQN filename:
read IQN
set iscsi-target iscsi:${boot-ip}::::${IQN}
echo iscsi-target = ${iscsi-target}
prompt Press any key to continue...
sanhook ${iscsi-target}
kernel ${boot-url}/wimboot pause
iseq ${platform} efi && initrd -n bootx64.efi ${boot-url}/bootx64.efi bootx64.efi ||
iseq ${platform} pcbios && initrd -n bootmgr ${boot-url}/bootmgr bootmgr ||
initrd -n BCD         ${boot-url}/boot/BCD           BCD ||
initrd -n boot.sdi    ${boot-url}/boot/boot.sdi      boot.sdi ||
initrd -n boot.wim    ${boot-url}/boot/boot.wim      boot.wim ||
prompt press any key to continue...
boot

:iscsib
set gateway 0.0.0.0
set keep-san 1
set initiator-iqn iqn.client
echo -n Enter IQN filename:
read IQN
set iscsi-target iscsi:${boot-ip}::::${IQN}
echo iscsi-target = ${iscsi-target}
prompt Press any key to continue...
sanboot ${iscsi-target}
boot

:winpe
kernel ${boot-url}/wimboot pause
iseq ${platform} efi && initrd -n bootx64.efi ${boot-url}/bootx64.efi bootx64.efi ||
iseq ${platform} pcbios && initrd -n bootmgr ${boot-url}/bootmgr bootmgr ||
initrd -n BCD         ${boot-url}/boot/BCD           BCD ||
initrd -n boot.sdi    ${boot-url}/boot/boot.sdi      boot.sdi ||
initrd -n boot.wim    ${boot-url}/boot/boot.wim      boot.wim ||
prompt press any key to continue...
boot

:config
config
goto main

:shell
shell
goto main

:exit
exit